shell其实就是一个由命令驱动的REPL. 你输入命令然后查看结果,然后输入另一个命令…如此往复. 如果输出结果只有几行,你会让它直接输出,如果输出结果有几百行,你会通过管道将结果传递给less命令.

不过在eshell中,你根本无需将结果传递给另一个pager,如果你发现输出结果太多内容了,只需要按下 C-c C-p 就会帮你跳到最后输入命令的头部,and then C-v your way down. 甚至于,你可以直接搜索你想要的那部分内容. 在eshell中执行命令意味着,这些命令的输出都会经过Emacs pager的处理.

更酷的是,你可以像Plan 9 那样启用Eshell的智能显示功能, 这时,执行命令后,如果命令输出过长,你的光标会自动留在输入命令的位置,直到你输入了一个非光标移动的键,光标才会跳到输入下一条命令的地方.

Eshell拥有如下几个优点:

• 它是由Emacs Lisp写成的, 因此它是跨平台的.
• 你不仅仅可以使用脚本和程序,你还可以使用Emacs函数… 想用Lisp写你的shell脚本?没问题!
• 它的使用体验也比一般的shell要好.

但是当一个程序想要直接操作终端时,就不适于Eshell了.^1

你可能也尝试过Eshell, 我想你一定为它的独特性所吸引. 现在让我们更近一步的了解它…

我的工作流是以Emacs所驱动的,偶尔才会用到shell. 我常常会在shell中输入一些命令后,然后回到原来的工作中. 当我想弹出一个shell时,我使用下列函数来创建一个指定buffer的window(该window位于原始window的下方,占三分之一的高度),并开启eshell(它会自动进入当前buffer的目录中).

(defun eshell-here ()
  "Opens up a new shell in the directory associated with the
current buffer's file. The eshell is renamed to match that
directory to make multiple eshell windows easier."
  (interactive)
  (let* ((parent (if (buffer-file-name)
                     (file-name-directory (buffer-file-name))
                   default-directory))
         (height (/ (window-total-height) 3))
         (name   (car (last (split-string parent "/" t)))))
    (split-window-vertically (- height))
    (other-window 1)
    (eshell "new")
    (rename-buffer (concat "*eshell: " name "*"))

    (insert (concat "ls"))
    (eshell-send-input)))

(global-set-key (kbd "C-!") 'eshell-here)

下面是我自定义的函数 x, 它会退出shell并关闭该window.

(defun eshell/x ()
  (insert "exit")
  (eshell-send-input)
  (delete-window))

EShell 同时也是一个 Lisp REPL. 下面是一些例子:

$ (message "hello world")
"hello world"

不过,在shell中,相比语法的清晰度我们更在意输入的简洁性与速度, 因此,在这种情况下,我们可以省略掉两边的括号:

$ message "hello world"
"hello world"

以 eshell/ 为前缀的函数在Eshell中执行时可以省略掉这个前缀, 也就是说你可以直接输入echo而实际调用的是 eshell/echo 函数:

$ echo "hello world"
"hello world"

不过如果你把函数调用放入括号内,则你需要输入函数的全称:

$ (eshell/echo "hello world")
"hello world"

那么传递的参数类型是什么呢? 在普通shell中,所有的参数都是字符串类型的,不过在Eshell中就不一定了:

$ echo hello world
("hello" "world")

结果是一个由两个字符串组成的list. 然而,你并不能把echo的结果传递给car… 至少不能直接传递过去:

$ car echo hello world

会返回一个错误, 下面这样也会报错:

$ car (list hello world)

你会发现,一点你把代码纳入括号内,你就必须严格遵守elisp的相关语法规定了,所以你应该这么做:

$ car (list "hello" "world")

EShell定义了一个名为 listify 的命令(译者注:这里严格来说是eshell/listify函数,但在eshell中不严格区分命令还是函数,所以按照shell的说法说成是命令了,下面在不区分函数或命令时也一样),能将传递给它的参数转换为字符串列表:

$ listify hello world
("hello" "world")

不过如果你想把这个命令的结果传递给别的命令,比如car,你需要将之用大括号括起来,它的意思是说,以shell的方式执行命令,但是将返回的结果作为lisp对象来对待:

$ car { listify hello world }
hello

目前我还没搞清楚 list 和 listify 之间的区别, 它们看起来作用是一样的:

$ listify hello world
("hello" "world")

$ list hello world
("hello" "world")

$ listify 1 2 3
(1 2 3)

$ list 1 2 3
(1 2 3)

$ list "hello world"
(#("hello world" 0 11
   (escaped t)))

$ listify "hello world"
(#("hello world" 0 11
   (escaped t)))

说了这么多,其实我的意思就是说,你既可以把Eshell当成是一个shell,也可以把它当成是一个Lisp REPL,你也可以既把它当成是shell也把它当成是Lisp REPL,只要你不要被搞糊涂了就成.

在Eshell的文档中有这么一段话

由于Eshell是基于Emacs的REPL(1), 它并没有自己的作用域, 因此它存储变量的方式跟你在Elisp程序中是一样的.

运行 printenv 会显示出那些环境变量,使用 setenv 来设置环境变量:

$ setenv A "hello world"
$ getenv A
"hello world"

使用 setq 来未普通的Emacs变量来赋值:

$ setq B hello world
$ echo $B
hello
$ setq B "hello world"
$ echo $B
hello world

通过在变量名前加 $, 你可以查看所有Emacs变量的值:

$ echo $recentf-max-menu-items
25

需要注意的是,同名的环境变量的值会覆盖Emacs普通变量的值:

$ setenv C hello
$ setq C goodbye
$ echo $C
hello

左后,你可以从文件中读取Eshell变量的设置:

$ cat blah.eshell
setq FOO 42
setq BLING "bongy"

$ . blah.eshell
42
bongy

$ echo $FOO
42

$ echo $BLING
bongy

在shell中经常需要逐个地处理多个文件. 在Eshell中,你既可以使用lisp中的dolist来实现,也可以使用类似shell的语法来实现:

$ for file in *.org {
  echo "Upcasing: $file"
  mv $file $file(:U)
}

上例中的 (:U)是一个转换器,会将它之前的内容转换为大写形式. 我会在下一部分内容对它中进行讲解(这也是Eshell最出色的特性之一).

你可能会发现,上例中的 *.org 传递给 for 循环语句的是一个用来迭代的list. 另外,如果有多于1个的参数传递给 for 时,也会创建一个list,例如:

$ for i in 1 2 3 4 { echo $i }

若传递给 for 的是多个list,则这些list会合并(flatten)成一个list, 因此你可以像下面这样操作:

$ for file in emacs* zsh* { ... }

若你要做的仅仅是重命名一个文件,或修改某个目录下所有文件的访问权限,那你根本无需用到shell,用dired甚至是Finder就足够了. shell只有在你想操作一部分匹配某模式的文件时才能比较方便. Eshell由于其特有的的filter(偷师于Zshell的modifiers)功能而尤为表现出众:

$ ls -al *.mp3(U)   # Show songs I own

上例中的 *.mp3 这部分就是我们所熟知的globbing pattern,而后面的(U)部分则进一步对结果进行了过滤. 在本例中,仅仅会输出宿主为你自己的那些文件.

你可以用下面两个命令来获取相关帮助信息:

$ eshell-display-predicate-help
$ eshell-display-modifier-help

你可能之前有接触过predicates(因为它们跟ZShell中的意义很接近), 不过更酷的是,你可以通过编写Elisp代码来新增自己的predicates 和 modifiers.

当然,EShell的精髓在于能与Emacs进行整合, 例如可以通过配置 highlight-regexp 来高亮输出中的关键字,还能将输出结果重定向到Emacs buffer中:

$ ls -al > #<buffer some-notes.org>

然后可以在结果中按下 C-c | 将输出结果转换成一个org-mode下的表格进行下一步的操作.

虽然Eshell内建于Emacs中,无需任何定制就能用,我还是做了一些改进以期能帮助到他人.

^1

像 top 这样的程序在Eshell中不能很好的工作,因为这种程序会尝试用原始的VT100控制代码来修改终端显示,然而Eshell假设所运行的程序输出的都是标准文本输出.

好在,在你输入 top 后, eshell会发现 top 被列在它的黑名单中了(准确地说,这种黑名单叫做eshell-visual-commands), 然后就会让它在一个特殊的comit buffer中显示.

在实践中,我根本没有注意到这个局限,因为大多数我使用的程序都实际上是被重写的Emacs函数. 不过如果你发现有个程序在Eshell中工作的不好,不妨试试把这个程序纳入到 eshell-visual-commands 这个列表中.